Added function to find out the volume name of a ProDOS 8 disk in a ProDOS 8 device.

git-svn-id: svn://svn.cc65.org/cc65/trunk@4668 b7a2c559-68d2-44c3-8de9-860c34a00d81
2010-05-26 21:02:35 +00:00
parent 096cb9c0a8
commit 05b23194d9
6 changed files with 73 additions and 8 deletions
--- a/libsrc/apple2/rootdir.s
+++ b/libsrc/apple2/rootdir.s
@@ -0,0 +1,52 @@
+;
+; Oliver Schmidt, 2010-05-24
+;
+; unsigned char __fastcall__ rootdir (unsigned char drive, char* buf);
+;
+
+        .export 	_rootdir
+        .import		popax
+
+        .include	"zeropage.inc"
+        .include	"errno.inc"
+        .include	"mli.inc"
+
+_rootdir:
+        ; Save buf
+        sta	ptr1
+        stx	ptr1+1
+
+        ; Set buf
+        sta	mliparam + MLI::ON_LINE::DATA_BUFFER
+        stx	mliparam + MLI::ON_LINE::DATA_BUFFER+1
+
+        ; Set drive
+        jsr	popax
+        sta	mliparam + MLI::ON_LINE::UNIT_NUM
+
+        ; Get volume name
+        lda	#ON_LINE_CALL
+        ldx	#ON_LINE_COUNT
+        jsr	callmli
+        bcs	:+
+
+        ; Get volume name length
+        ldy	#$00
+        lda	(ptr1),y
+        and	#15		; Max volume name length
+        sta	tmp1
+        
+        ; Add leading slash
+        lda	#'/'
+        sta	(ptr1),y
+
+	; Add terminating zero
+        ldy	tmp1
+        iny        
+        lda	#$00
+        sta	(ptr1),y
+        
+        ; Return success or error
+:       sta	__oserror
+        ldx	#$00
+        rts