Adapted, to the c64 target, the INIT-segment overlay scheme from the apple2 targets.

When a program starts running, INIT is moved from one place to another place. Then, INIT's code is executed; and, the first place is re-used for variables. After the INIT code has finished, the second place can be re-used by the heap and the C stack. That means that initiation code and data won't waste any RAM space after they stop being needed.
2015-10-05 05:47:43 -04:00
parent 24c2da980b
commit 074e10d288
5 changed files with 200 additions and 104 deletions
--- a/libsrc/common/moveinit.s
+++ b/libsrc/common/moveinit.s
@@ -0,0 +1,54 @@
+;
+; 2015-10-04, Greg King
+;
+
+        .export         move_init
+
+        .import         __INIT_LOAD__, __INIT_RUN__, __INIT_SIZE__ ; Linker-generated
+        .importzp       init_load_, init_run_
+
+        .macpack        cpu
+        .macpack        generic
+
+
+; Move the INIT segment from where it was loaded (over the bss segments)
+; into where it must be run (in the heap).  The two areas might overlap; and,
+; the segment is moved upwards.  Therefore, this code starts at the highest
+; address, and decrements to the lowest address.  The low bytes of the starting
+; pointers are not sums.  The high bytes are sums; but, they do not include the
+; carry.  Both the low-byte sums and the carries will be done when the pointers
+; are indexed by the .Y register.
+
+move_init:
+        lda     #<__INIT_LOAD__
+        ldx     #>__INIT_LOAD__ + >__INIT_SIZE__
+        sta     init_load_
+        stx     init_load_+1
+        lda     #<__INIT_RUN__
+        ldx     #>__INIT_RUN__ + >__INIT_SIZE__
+        sta     init_run_
+        stx     init_run_+1
+
+; First, move the last, partial page.
+; Then, move all of the full pages.
+
+        ldx     #>__INIT_SIZE__ + 1     ; number of pages, including partial
+        ldy     #<__INIT_SIZE__         ; size of partial page
+.if     .cpu & CPU_ISET_65SC02
+        bra     L3
+.else
+        jmp     L3
+.endif
+
+L1:     dec     init_load_+1
+        dec     init_run_+1
+
+L2:     dey
+        lda     (init_load_),y
+        sta     (init_run_),y
+        tya
+L3:     bnz     L2                      ; page not finished
+
+        dex
+        bnz     L1                      ; move next page
+        rts