Added 16*16=32 multiplication routine.

git-svn-id: svn://svn.cc65.org/cc65/trunk@4434 b7a2c559-68d2-44c3-8de9-860c34a00d81
2009-11-03 13:40:03 +00:00
parent 6078953baa
commit 0c1703f8fd
3 changed files with 54 additions and 4 deletions
--- a/libsrc/runtime/mul16x16r32.s
+++ b/libsrc/runtime/mul16x16r32.s
@@ -0,0 +1,49 @@
+;
+; Ullrich von Bassewitz, 2010-11-03
+;
+; CC65 runtime: 16x16 => 32 multiplication
+;
+
+        .export         umul16x16r32
+       	.export	       	mul16x16r32 := umul16x16r32
+    	.importzp   	ptr1, ptr2, ptr3, ptr4, sreg
+
+
+;---------------------------------------------------------------------------
+; 16x16 => 32 multiplication routine.
+;
+;   lhs         rhs           result          result also in
+; -------------------------------------------------------------
+;   ptr1        ptr3           ax:sreg          ptr1:sreg
+;
+
+umul16x16r32:
+       	lda	#0
+       	ldx	ptr3+1	       	; Get high byte into register for speed
+       	sta    	sreg+1
+       	ldy    	#16   	       	; Number of bits
+
+        lsr     ptr1+1
+        ror     ptr1            ; Get first bit into carry
+@L0:    bcc     @L1
+
+      	clc
+      	adc	ptr3
+      	pha
+       	txa	      	       	; hi byte of left op
+      	adc	sreg+1
+      	sta	sreg+1
+      	pla
+
+@L1:    ror     sreg+1
+     	ror	a
+     	ror	ptr1+1
+     	ror	ptr1
+        dey
+        bne     @L0
+
+        sta     sreg            ; Save byte 3
+      	lda	ptr1	       	; Load the result
+      	ldx	ptr1+1
+      	rts	    		; Done
+