Rewrote fprintf in assembler

git-svn-id: svn://svn.cc65.org/cc65/trunk@513 b7a2c559-68d2-44c3-8de9-860c34a00d81

libsrc/common/fprintf.s

@@ -0,0 +1,70 @@
+;
+; int printf (const char* Format, ...);
+;
+; Ullrich von Bassewitz, 1.12.2000
+;
+
+	.export	      	_fprintf
+	.import		pushax, addysp, subysp, _vfprintf
+	.importzp	sp, ptr1
+
+	.macpack	generic
+
+; ----------------------------------------------------------------------------
+; Data
+
+.bss
+
+ParamSize: 	.res  	1		; Number of parameter bytes
+
+; ----------------------------------------------------------------------------
+; Code
+
+.code
+
+
+_fprintf:
+  	sty	ParamSize		; Number of param bytes passed in Y
+
+; We have to push f and format, both in the order they already have on stack.
+; To make this somewhat more efficient, we will create space on the stack and
+; the do a copy of the complete block instead of pushing each parameter
+; separately. Since the size of the arguments passed is the same as the size
+; of the fixed arguments, this will allow us to calculate the pointer to the
+; fixed size arguments easier (they're just ParamSize bytes away).
+
+	ldy	#4
+	jsr	subysp
+
+; Calculate a pointer to the Format argument
+
+	lda	ParamSize
+	add	sp
+	sta	ptr1
+	ldx	sp+1
+	bcc	@L1
+	inx
+@L1:	stx	ptr1+1
+
+; Now copy both, f and format
+
+	ldy	#4-1
+@L2:	lda	(ptr1),y
+	sta	(sp),y
+	dey
+	bpl	@L2
+
+; Load va_list (last and __fastcall__ parameter to vfprintf)
+
+	lda    	ptr1
+	ldx    	ptr1+1
+
+; Call vfprintf
+
+	jsr	_vfprintf
+
+; Cleanup the stack. We will return what we got from vfprintf
+
+	ldy	ParamSize
+	jmp	addysp
+