Merge pull request #626 from blackystardust/master

Added c64dtv accelerator code and documentation.

libsrc/c64/acc_c64dtv_speed.s

@@ -0,0 +1,64 @@
+;
+; Marco van den Heuvel, 2018-04-14
+;
+
+; extern unsigned char __fastcall__ set_c64dtv_speed (unsigned char speed);
+;
+;/* Set the speed of the C64DTV, using SPEED_SLOW will switch to
+; * slow mode, SPEED_2X or SPEED_FAST will switch to fast mode.
+; *
+; * Note that any value higher or equal to SPEED_2X will switch to fast mode.
+; *
+; * This function will return the actual speed the CPU is at after trying
+; * to set the requested speed, to my knowledge the switching should not fail.
+; *
+; * This function does not check for the presence of the C64DTV,
+; * make sure you use 'detect_c64dtv();' before using.
+; */
+
+; extern unsigned char get_c64dtv_speed (void);
+;
+;/* Get the speed of the C64DTV.
+; *
+; * Possible return values:
+; * SPEED_1X    : slow mode
+; * SPEED_2X    : fast mode
+; *
+; * This function does not check for the presence of the C64DTV,
+; * make sure you use 'detect_c64dtv();' before using.
+; */
+
+        .export         _set_c64dtv_speed
+        .export         _get_c64dtv_speed
+
+        .include        "accelerator.inc"
+
+_set_c64dtv_speed:
+        cmp     #SPEED_2X
+        bcs     high_speed
+low_speed:
+        ldx     #C64DTV_Slow
+set_speed:
+        .byte   $32,$99               ; SAC #$99   set accumulator to reg 9 (cpu control)
+        txa                           ; (re)set skip and burst bits
+        .byte   $32,$00               ; SAC #$00   set accumulator back to reg 0
+        jmp     _get_c64dtv_speed
+
+high_speed:
+        ldx     #C64DTV_Fast
+        bne     set_speed
+
+
+_get_c64dtv_speed:
+        .byte   $32,$99               ; SAC #$99   set accumulator to reg 9 (cpu control)
+        tax
+        .byte   $32,$00               ; SAC #$00   set accumulator back to reg 0
+        txa
+        and     #C64DTV_Fast
+        bne     in_fast_mode
+        lda     #$00
+        .byte   $2C
+in_fast_mode:
+        lda     #$01
+        ldx     #$00
+        rts

libsrc/c64/acc_detect_c64dtv.s

@@ -0,0 +1,44 @@
+;
+; Marco van den Heuvel, 2018-04-14
+;
+
+; unsigned char detect_c64dtv (void);
+;
+;/* Check for the presence of the C64DTV.
+; *
+; * Possible return values:
+; * 0x00  : C64DTV not present
+; * 0x01  : C64DTV present
+; */
+
+        .export         _detect_c64dtv
+
+        .include        "accelerator.inc"
+
+_detect_c64dtv:
+        ldy     C64DTV_Extended_Regs
+        lda     #$00
+        ldx     $D000
+
+; Make sure the CPU is a 6510
+        .byte   $1A                   ; NOP on 8502, INA on 65(S)C(E)02, 4510 and 65816
+        bne     not_found
+        lda     #$01
+        sta     C64DTV_Extended_Regs
+
+; Check if $D000 is mirrored at $D040
+        cpx     $D040
+        bne     found
+        inc     $D000
+        cpx     $D040
+        bne     not_found
+found:
+        lda     #$01
+        .byte   $2C
+not_found:
+        lda     #$00
+        stx     $D000
+        ldx     #$00
+        sty     C64DTV_Extended_Regs
+        rts
+