Rewrote fclose() in assembler

git-svn-id: svn://svn.cc65.org/cc65/trunk@1621 b7a2c559-68d2-44c3-8de9-860c34a00d81
2002-11-24 19:13:38 +00:00
parent 0cd1141f60
commit 5d0ebf8b96
4 changed files with 53 additions and 29 deletions
--- a/libsrc/common/fclose.s
+++ b/libsrc/common/fclose.s
@@ -0,0 +1,52 @@
+;
+; Ullrich von Bassewitz, 22.11.2002
+;
+; int __fastcall__ fclose (FILE* f);
+; /* Close a file */
+;
+
+        .export         _fclose
+
+        .import         _close
+        .importzp       ptr1                                   
+
+        .include        "errno.inc"
+        .include        "_file.inc"
+
+; ------------------------------------------------------------------------
+; Code
+
+.proc   _fclose
+
+        sta     ptr1
+        stx     ptr1+1          ; Store f
+
+; Check if the file is really open
+
+        ldy     #_FILE_f_flags
+        lda     (ptr1),y
+        and     #_FOPEN
+        bne     @L1
+
+; File is not open
+
+        lda     #EINVAL
+        sta     __errno
+        ldx     #0
+        stx     __errno+1
+        dex
+        txa
+        rts
+
+; File is open. Reset the flags and close the file.
+
+@L1:    lda     #_FCLOSED
+        sta     (ptr1),y
+
+        ldy     #_FILE_f_fd
+        lda     (ptr1),y
+        ldx     #0
+        jmp     _close          ; Will set errno and return an error flag
+
+.endproc
+