cbm stuff from greggs pull request
This commit is contained in:
mrdudz
53
libsrc/cbm/cpeekc.s
Normal file
53
libsrc/cbm/cpeekc.s
Normal file
@@ -0,0 +1,53 @@
|
||||
;
|
||||
; 2016-02-28, Groepaz
|
||||
; 2017-06-22, Greg King
|
||||
;
|
||||
; char cpeekc (void);
|
||||
;
|
||||
|
||||
.export _cpeekc
|
||||
|
||||
; Get a system-specific file.
|
||||
; Note: The cbm610, and c128 targets need special
|
||||
; versions that handle RAM banking and the 80-column VDC.
|
||||
|
||||
.if .def(__C16__)
|
||||
.include "plus4.inc" ; both C16 and Plus4
|
||||
.elseif .def(__C64__)
|
||||
.include "c64.inc"
|
||||
.elseif .def(__CBM510__)
|
||||
.import CURS_X: zp, SCREEN_PTR: zp
|
||||
.include "cbm510.inc"
|
||||
.elseif .def(__PET__)
|
||||
.include "pet.inc"
|
||||
.elseif .def(__VIC20__)
|
||||
.include "vic20.inc"
|
||||
.endif
|
||||
|
||||
|
||||
_cpeekc:
|
||||
ldy CURS_X
|
||||
lda (SCREEN_PTR),y ; get screen code
|
||||
ldx #>$0000
|
||||
and #<~$80 ; remove reverse bit
|
||||
|
||||
; Convert the screen code into a PetSCII code.
|
||||
; $00 - $1F: +$40
|
||||
; $20 - $3F
|
||||
; $40 - $5f: +$20
|
||||
; $60 - $7F: +$40
|
||||
|
||||
cmp #$20
|
||||
bcs @sk1 ;(bge)
|
||||
ora #$40
|
||||
rts
|
||||
|
||||
@sk1: cmp #$40
|
||||
bcc @end ;(blt)
|
||||
cmp #$60
|
||||
bcc @sk2 ;(blt)
|
||||
;sec
|
||||
adc #$20 - $01
|
||||
@sk2: ;clc ; both above cmp and adc clear carry flag
|
||||
adc #$20
|
||||
@end: rts
|
||||
28
libsrc/cbm/cpeekcolor.s
Normal file
28
libsrc/cbm/cpeekcolor.s
Normal file
@@ -0,0 +1,28 @@
|
||||
;
|
||||
; 2016-02-28, Groepaz
|
||||
; 2017-06-22, Greg King
|
||||
;
|
||||
; unsigned char cpeekcolor (void);
|
||||
;
|
||||
|
||||
.export _cpeekcolor
|
||||
|
||||
; Get a system-specific file.
|
||||
; Note: The cbm510, cbm610, c128, and Pet targets need special
|
||||
; versions that handle RAM banking, the 80-column VDC, and monochrome.
|
||||
|
||||
.if .def(__C16__)
|
||||
.include "plus4.inc" ; both C16 and Plus4
|
||||
.elseif .def(__C64__)
|
||||
.include "c64.inc"
|
||||
.elseif .def(__VIC20__)
|
||||
.include "vic20.inc"
|
||||
.endif
|
||||
|
||||
|
||||
_cpeekcolor:
|
||||
ldy CURS_X
|
||||
lda (CRAM_PTR),y ; get color
|
||||
and #$0F
|
||||
ldx #>$0000
|
||||
rts
|
||||
35
libsrc/cbm/cpeekrevers.s
Normal file
35
libsrc/cbm/cpeekrevers.s
Normal file
@@ -0,0 +1,35 @@
|
||||
;
|
||||
; 2016-02-28, Groepaz
|
||||
; 2017-06-15, Greg King
|
||||
;
|
||||
; unsigned char cpeekrevers (void);
|
||||
;
|
||||
|
||||
.export _cpeekrevers
|
||||
|
||||
; Get a system-specific file.
|
||||
; Note: The cbm610, and c128 targets need special
|
||||
; versions that handle RAM banking and the 80-column VDC.
|
||||
|
||||
.if .def(__C16__)
|
||||
.include "plus4.inc" ; both C16 and Plus4
|
||||
.elseif .def(__C64__)
|
||||
.include "c64.inc"
|
||||
.elseif .def(__CBM510__)
|
||||
.import CURS_X: zp, SCREEN_PTR: zp
|
||||
.include "cbm510.inc"
|
||||
.elseif .def(__PET__)
|
||||
.include "pet.inc"
|
||||
.elseif .def(__VIC20__)
|
||||
.include "vic20.inc"
|
||||
.endif
|
||||
|
||||
|
||||
_cpeekrevers:
|
||||
ldy CURS_X
|
||||
lda (SCREEN_PTR),y ; get screen code
|
||||
and #$80 ; get reverse bit
|
||||
asl a
|
||||
tax ; ldx #>$0000
|
||||
rol a ; return boolean value
|
||||
rts
|
||||
93
libsrc/cbm/cpeeks.s
Normal file
93
libsrc/cbm/cpeeks.s
Normal file
@@ -0,0 +1,93 @@
|
||||
;
|
||||
; 2017-07-05, Greg King
|
||||
;
|
||||
; void cpeeks (char* s, unsigned length);
|
||||
;
|
||||
|
||||
.export _cpeeks
|
||||
|
||||
.import popax
|
||||
.importzp ptr1, ptr2, ptr3, tmp1, tmp2
|
||||
|
||||
.macpack generic
|
||||
|
||||
; Get a system-specific file.
|
||||
; Note: The cbm610, and c128 targets need special
|
||||
; versions that handle RAM banking and the 80-column VDC.
|
||||
|
||||
.if .def(__C16__)
|
||||
.include "plus4.inc" ; both C16 and Plus4
|
||||
.elseif .def(__C64__)
|
||||
.include "c64.inc"
|
||||
.elseif .def(__CBM510__)
|
||||
.import CURS_X: zp, SCREEN_PTR: zp
|
||||
.include "cbm510.inc"
|
||||
.elseif .def(__PET__)
|
||||
.include "pet.inc"
|
||||
.elseif .def(__VIC20__)
|
||||
.include "vic20.inc"
|
||||
.endif
|
||||
|
||||
|
||||
_cpeeks:
|
||||
eor #<$FFFF ; counting a word upward is faster
|
||||
sta ptr3 ; so, we use -(length + 1)
|
||||
txa
|
||||
eor #>$FFFF
|
||||
sta ptr3+1
|
||||
|
||||
lda SCREEN_PTR
|
||||
ldx SCREEN_PTR+1
|
||||
sta ptr2
|
||||
stx ptr2+1
|
||||
ldy CURS_X
|
||||
sty tmp2
|
||||
|
||||
jsr popax
|
||||
sta tmp1 ; (will be a .Y index)
|
||||
stx ptr1+1
|
||||
ldx #<$0000
|
||||
stx ptr1
|
||||
bze L3 ; branch always
|
||||
|
||||
L4: ldy tmp2
|
||||
lda (ptr2),y ; get char
|
||||
iny
|
||||
bnz L2
|
||||
inc ptr2+1
|
||||
L2: sty tmp2
|
||||
and #<~$80 ; remove reverse bit
|
||||
|
||||
; Convert the screen code into a PetSCII code.
|
||||
; $00 - $1F: +$40
|
||||
; $20 - $3F
|
||||
; $40 - $5f: +$20
|
||||
; $60 - $7F: +$40
|
||||
|
||||
cmp #$20
|
||||
blt @sk1 ;(bcc)
|
||||
cmp #$40
|
||||
blt L5
|
||||
cmp #$60
|
||||
blt @sk2 ;(bcc)
|
||||
clc
|
||||
@sk1: adc #$20
|
||||
@sk2: ;clc ; both above cmp and adc clear carry flag
|
||||
adc #$20
|
||||
|
||||
L5: ldy tmp1
|
||||
sta (ptr1),y
|
||||
iny
|
||||
bnz L1
|
||||
inc ptr1+1
|
||||
L1: sty tmp1
|
||||
|
||||
L3: inc ptr3 ; count length
|
||||
bnz L4
|
||||
inc ptr3+1
|
||||
bnz L4
|
||||
|
||||
txa ; terminate the string
|
||||
ldy tmp1
|
||||
sta (ptr1),y
|
||||
rts
|
||||
Reference in New Issue
Block a user