Merge pull request #629 from blackystardust/master

Added C128 accelerator code and documentation for both C128 mode and C128 in C64 mode.

libsrc/c128/acc_c128_speed.s

@@ -0,0 +1,56 @@
+;
+; Marco van den Heuvel, 2018-04-23
+;
+
+; extern unsigned char __fastcall__ set_c128_speed (unsigned char speed);
+;
+;/* Set the speed of the C128 8502 CPU, using SPEED_SLOW will switch to
+; * 1 Mhz (slow) mode, SPEED_2X or SPEED_FAST will switch to 2Mhz (fast) mode.
+; *
+; * Note that any value higher or equal to SPEED_2X will switch to fast mode.
+; *
+; * This function will return the actual speed the CPU is at after trying
+; * to set the requested speed, to my knowledge the switching should not fail.
+; *
+; * For C64 programs a check for a C128 in C64 mode is needed, make sure you
+; * use 'detect_c128();' before using.
+; *
+; * For C128 programs no detect function call is needed.
+; */
+
+; extern unsigned char get_c128_speed (void);
+;
+;/* Get the speed of the C128 8502 CPU.
+; *
+; * Possible return values:
+; * SPEED_SLOW  : Slow mode
+; * SPEED_2X    : Fast mode
+; *
+; * For C64 programs a check for a C128 in C64 mode is needed, make sure you
+; * use 'detect_c128();' before using.
+; *
+; * For C128 programs no detect function call is needed.
+; */
+
+        .export         _set_c128_speed
+        .export         _get_c128_speed
+
+        .include        "accelerator.inc"
+
+_set_c128_speed:
+        cmp     #SPEED_2X
+        bcs     high_speed
+store_speed:
+        sta     C128_VICIIE_CLK
+
+        .byte   $2C              ; skip over the lda #$01
+high_speed:
+        lda     #$01
+        bne     store_speed
+
+_get_c128_speed:
+        lda     C128_VICIIE_CLK
+        and     #$01
+        ldx     #$00
+        rts
+

libsrc/c128/acc_detect_c128.s

@@ -0,0 +1,24 @@
+;
+; Marco van den Heuvel, 2018-04-23
+;
+
+; unsigned char detect_c128 (void);
+;
+;/* Check if the C128 8502 CPU is the current CPU.
+; *
+; * Possible return values:
+; * 0x00  : C128 8502 is not the current CPU
+; * 0x01  : C128 8502 is the current CPU
+; */
+
+        .export         _detect_c128
+
+        .include        "accelerator.inc"
+
+_detect_c128:
+        ldx     #$00
+        lda     #$01
+
+; Make sure the CPU is a 8502
+        .byte   $3A                   ; NOP on 8502, DEA on 65(S)C(E)02, 4510 and 65816
+        rts

libsrc/c64/acc_c128_speed.s

@@ -0,0 +1,6 @@
+;
+; Marco van den Heuvel, 2018-04-23
+;
+
+.include "../c128/acc_c128_speed.s"
+

libsrc/c64/acc_detect_c128.s

@@ -0,0 +1,36 @@
+;
+; Marco van den Heuvel, 2018-04-20
+;
+
+; unsigned char detect_c128 (void);
+;
+;/* Check for the presence of a C128 in C64 mode.
+; *
+; * Possible return values:
+; * 0x00  : C128 in C64 mode not present
+; * 0x01  : C128 in C64 mode present
+; */
+
+        .export         _detect_c128
+
+        .include        "accelerator.inc"
+
+_detect_c128:
+        lda     #$00
+        tax
+
+; Make sure the CPU is a 8502
+        .byte   $1A                   ; NOP on 8502, INA on 65(S)C(E)02, 4510 and 65816
+        beq     found
+        .byte   $3A                   ; decrement A again, so a #$00 can be returned
+        rts
+
+found:
+
+; Make sure a C128 VICIIe is present
+        ldy     C128_VICIIE_CLK
+        cpy     #$FF
+        beq     not_found
+        lda     #$01
+not_found:
+        rts