816666615b
Add a machinetype identifier to help us quickly identify Apple //e (bit 7) and //e enhanced (bit 6). Use it in conio functions for 80-columns code instead of relying entirely on the __APPLE2ENH__ target. Move videomode() to the apple2 target, and have it return an error if 80-columns hardware is not available - this is a lie for now, it is considered available on //e enhanced, which may not be true, and not available on //e, which may also be not true. An ulterior patch will make that check correctly. Adapt the box/line drawing characters so that one can use MouseText on the apple2 target if it is available, by defining DYN_DRAW_BOX. No change by default: MouseText is considered available on apple2enh and not available on apple2.
61 lines
1.5 KiB
ArmAsm
61 lines
1.5 KiB
ArmAsm
;
|
|
; Kevin Ruland
|
|
;
|
|
; char cgetc (void);
|
|
;
|
|
; If open_apple key is pressed then the high-bit of the key is set.
|
|
;
|
|
|
|
.export _cgetc
|
|
|
|
.ifndef __APPLE2ENH__
|
|
.import machinetype
|
|
.endif
|
|
.import cursor, putchardirect
|
|
|
|
.include "zeropage.inc"
|
|
.include "apple2.inc"
|
|
|
|
_cgetc:
|
|
; Cursor on ?
|
|
lda cursor
|
|
beq :+
|
|
|
|
; Show caret.
|
|
.ifndef __APPLE2ENH__
|
|
lda #' ' | $40 ; Blank, flashing
|
|
bit machinetype
|
|
bpl put_caret
|
|
.endif
|
|
|
|
lda #$7F | $80 ; Checkerboard, screen code
|
|
put_caret:
|
|
jsr putchardirect ; Saves old character in tmp3
|
|
|
|
; Wait for keyboard strobe.
|
|
: inc RNDL ; Increment random counter low
|
|
bne :+
|
|
inc RNDH ; Increment random counter high
|
|
: lda KBD
|
|
bpl :-- ; If < 128, no key pressed
|
|
|
|
; Cursor on ?
|
|
ldy cursor
|
|
beq :+
|
|
|
|
; Restore old character.
|
|
pha
|
|
lda tmp3
|
|
jsr putchardirect
|
|
pla
|
|
|
|
; At this time, the high bit of the key pressed is set.
|
|
: bit KBDSTRB ; Clear keyboard strobe
|
|
.ifdef __APPLE2ENH__
|
|
bit BUTN0 ; Check if OpenApple is down
|
|
bmi done
|
|
.endif
|
|
and #$7F ; If not down, then clear high bit
|
|
done: ldx #>$0000
|
|
rts
|